汇编语言的进制显示

如果要处理一个与数相关的问题,不管是中间的、还是最终的结果，我们都

希望能直观地在显示器上显示出来。数字计算机中的数据存储方式是由“0”和“1”组成的二进制码串，根据不同的需要,我们往往要求数据的显示形式不一样，如二进制、十进制、十六进制、八进制等等，然而在汇编语言中实现数据的显示没有类似高级语言中的输出格式命令那么方便，对每个数的显示，一般都需要逐位地转换成ASCII码才能调用系统显示功能完成显示，其中，按不同的数制要求，还要先完成数制间的转换。下面我们来探讨一个数如何编程让它分别按二进制、十进制、十六进制的数制形式显示在显示器上。

二、编程思路与算法

以一个16位二进制机器整数为例,它的二进制表示范围是0至1111111111111111B；十进制的范围是0至65535(无符号数)，或-32768

至+32767（有符号数）；十六进制表示范围是0000至FFFFH。为方便说明，

假设此数放在BX寄存器中，下面介绍按不同进制形式显示的编程思路和算法。

（一）按二进制形式显示

二进制只有“0”和“1”两个数字，它们的ASCII码分别是30H和31H，只

要逐位判断是“0”还是“1”，然后转换成对应的ASCII码即可。

实际编程时，对于BX中的十六位二进制数，可设置一个循环次数为16的

循环体，用向左的移位指令，通过CPU标志寄存器中的CF标志，由高位到低

位逐位判断、逐位取ASCII码值、逐位显示。当然也可以先将十六个数位都转

换成一个ASCII码串放入内存缓冲区后再按字符串方式显示，要注意2种方法

在显示时系统调用的功能号不同。

（二）按十进制形式显示

首先要完成二进制到十进制数的转换，一般采用“除10取余”法来完成，其

大致过程如下：将待转换的数（在BX中）除以10，得到第一个商和余数，此

第一个余数就是所求的十进制数的个位；再用第一个商除以10，得到第二个商

和余数，此第二个余数就是所求十进制数的十位；……；重复这一过程直至商为

0，此时的余数就是所求十进制数的最高位。

在内存中分配一缓冲区，用来存放以上分离出来的十进制数的每一位，然

后再逐个转换成ASCII码，转换成ASCII码的过程很简单，就是给每个十进制

位加上30H即可；最后送显示器输出。从转换的过程可以看出，先分离出来的

是十进制数的低位，要后显示；后分离出来的是十进制数的高位，应该先显示。

因此在编程时，我们可以利用堆栈操作中“先进后出、后进先出”的特性，当分离出各十进制位时依次入栈，要逐个转换成ASCII码，显示时依次出栈。

（三）按十六进制形式显示

十六进制与二进制有很好的对应关系（每4位二进制数和1位十六进制数

存在一一对应关系），显示时只需将原二进制数（在BX中）每4位分成一组，

按组求对应的ASCII码送显示器即可。

ASCII码与十六进制数字的对应关系为：30H~39H对应数字0~9，41H~46H对应数字A~F，从数字9到A，其ASCII码间隔了7H，这一点在转换时要特别注意。为使一个十六进制数能按高位到低位依次显示，实际编程中，我们对先BX中的数每次循环左移一组（4位二进制），然后屏蔽掉当前高12位，对当前余下的4位（即1位十六进制数）求其ASCII码，要判断它是0~9还是A~F，是前者则加30H得对应的ASCII码，后者则要加37H才行，最后送显示器输出。以上步骤重复4次，就可以完成BX中数以4位十六进制的

形式显示出来。

三、汇编语言源程序实例

假设要将BX寄存器中的数分别按无符号二进制、十进制和十六进制显示在

屏幕上，下面给出实现的汇编源程序，均为子程序方式，为了简明，略去现场的

保护与恢复操作。

（一）按二进制形式

DISPBXB PROC NEAR

MOV CX,16

LP:ROL BX,1

JC D1

MOV DL,30H

JMP OUTP

D1:MOV DL,31H

OUTP:MOV AH,2

INT 21H

LOOP LP

MOV DL,’B’;显示字母“B”

MOV AH,2

INT 21H

RET

DISPBXB ENDP

设(BX)=7FFFH，则输出格式为0111111111111111B，后面的大写

字母B表示二进制形式，显示结果固定为十六位。

（二）按十进制形式

DISPBXD PROC NEAR

MOV SI,10

XOR CX,CX

MOV AX,BX

NEXT:MOV DX,0

DIV SI

PUSH DX

INC CX

CMP AX,0;商为0则完成转换

JNZ NEXT

OUTP:POP DX

ADD DL,30H

MOV AH,2

INT 21H

LOOP OUTP

RET

DISPBXD ENDP

此程序在转换和显示时的循环控制方式和二进制形式的例子不一样，即显示

结果的位数是不固定的。若（BX）=7FFFH=32767，则显示结果为5位：32767；

若（BX）=00FFH=255，则显示结果为3位：255，与十进制的有效位数相

同。

（三）按十六进制形式

DISPBXH PROC NEAR

MOV CL,4

MOV CH,4

NEXT:ROL BX, CL

MOV AL,BL

AND AL,0FH

ADD AL,30H

CMP AL,3AH

JL OUTP

ADD AL,07H;是A~F，要多加7

OUTP:MOV DL,AL

MOV AH,02H

INT 21H

DEC CH

CMP CH,0

JA NEXT

MOV DL,’H’；显示字母“H”

MOV AH,2

INT 21H

RET

DISPBXH ENDP

此程序的显示格式固定为4位，最后加上字母“H”表示为十六进制形式。设

（BX）=7FFFH，则显示结果为：7FFFH；若（BX）=00FFH，则显示结果为：

00FFH。

四、对有符号数显示的扩展应用

CMP BX,0

JGE ZS

MOV DL,’-’

MOV AH,2

INT 21H

ZS:CALL DISPBXD

五、结语

以上介绍了在汇编语言程序设计中，根据不同的需要，如何把机器数按不同

数制形式显示出来的方法，对于不具体介绍的八进制形式，只需将十进制显示的

子程序（DISPBXD）中的除数由10改为8即可。各种方法中，主要是数据转

换的方法不同，显示的功能调用指令是一样的，当然还可以用其他（比如字符串方式）方法调用显示功能，这里不再详细介绍。